dnl Process this file with autoconf to produce a configure script.

AC_INIT([openmoocow],[0.4.0+git],[taw@bitwiz.org.uk])
VERSION=AC_PACKAGE_VERSION

AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE(openmoocow, "$VERSION")

AC_PROG_CC
AC_PROG_AWK
AC_PROG_INSTALL
AC_PROG_LN_S

AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
AC_C_CONST
AC_FUNC_MALLOC
AC_CHECK_FUNCS([strdup])

if test -z "$PKG_CONFIG"; then
	AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
fi
if test "$PKG_CONFIG" = "no" ; then
	echo "*** pkg-config not found.  Do you have pkg-config installed?"
fi

PKG_CHECK_MODULES([GTK3], [gtk+-3.0 > 2.90.0],
[

     AC_DEFINE([HAVE_GTK3], [1], [Define to 1 if GTK3 is available])
     GTK2_CFLAGS=""
     GTK2_LIBS=""

], [

  PKG_CHECK_MODULES([GTK2], [gtk+-2.0 > 2.0.0],
  [

      AC_DEFINE([HAVE_GTK2], [1], [Define to 1 if GTK2 is available])
      GTK3_CFLAGS=""
      GTK3_LIBS=""

  ], [
      AC_MSG_ERROR([*** You need at least GTK+-2.0 to compile OpenMooCow])
  ])

])



AC_MSG_CHECKING([SDL])
if $PKG_CONFIG sdl ; then
        LIBSDL_CFLAGS=`$PKG_CONFIG --cflags sdl`
        LIBSDL_LIBS=`$PKG_CONFIG --libs sdl`
        AC_MSG_RESULT([yes])
else
        AC_MSG_RESULT([not found])
        AC_MSG_ERROR([*** SDL not found.  Do you have 'libsdl-dev' or similar installed?])
fi

CFLAGS="$CFLAGS $GTK2_CFLAGS $GTK3_CFLAGS $LIBSDL_CFLAGS"
LIBS="$LIBS $GTK2_LIBS $GTK3_LIBS $LIBSDL_LIBS -lgthread-2.0"

AC_CONFIG_FILES([Makefile src/Makefile data/Makefile])
AC_OUTPUT