blob: c7d1de046aea3037b3cda552b81843aa7ee2ede5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
|
;;
;; starlet/colours.scm
;;
;; Copyright © 2020-2021 Thomas White <taw@bitwiz.org.uk>
;;
;; This file is part of Starlet.
;;
;; Starlet is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;;
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;
(define-module (starlet colours)
#:use-module (oop goops)
#:use-module (ice-9 exceptions)
#:export (<colour>
colour?
make-colour-cmy
make-colour-rgb
colour-as-cmy
colour-as-rgb
cyan
magenta
yellow
red
green
blue
interpolate-colour
white
<colour-component-id>
colour-component-id?
colour-component-id
get-colour-component
extract-colour-component))
(define-class <colour> (<object>)
(type
#:init-form (error "Colour type must be specified")
#:init-keyword #:type
#:getter colour-type)
(value
#:init-form (error "Colour value must be specified")
#:init-keyword #:value
#:getter colour-value))
(define (colour? c)
(is-a? c <colour>))
(define cyan car)
(define magenta cadr)
(define yellow caddr)
(define red car)
(define green cadr)
(define blue caddr)
(define-method (display (col <colour>) port)
(format port "#<<colour> ~a ~a>"
(colour-type col)
(colour-value col)))
(define-method (write (col <colour>) port)
(let ((cmy (colour-as-cmy col)))
(format port "(make-colour-cmy ~a ~a ~a)"
(cyan cmy)
(magenta cmy)
(yellow cmy))))
(define (make-colour-cmy c m y)
(make <colour>
#:type 'cmy
#:value (list c m y)))
(define (make-colour-rgb r g b)
(make <colour>
#:type 'rgb
#:value (list r g b)))
(define white
(make-colour-cmy 0 0 0))
(define (colour-as-rgb col)
(let ((val (colour-value col)))
(case (colour-type col)
((rgb)
val)
((cmy)
(list (- 100 (red val))
(- 100 (green val))
(- 100 (blue val))))
(else
(raise-exception (make-exception
(make-exception-with-message "Unrecognised colour type")
(make-exception-with-irritants (colour-type col))))))))
(define (colour-as-cmy col)
(let ((val (colour-value col)))
(case (colour-type col)
((cmy)
val)
((rgb)
(list (- 100 (red val))
(- 100 (green val))
(- 100 (blue val))))
(else
(raise-exception (make-exception
(make-exception-with-message "Unrecognised colour type")
(make-exception-with-irritants (colour-type col))))))))
(define (interpolate-cmy a b frac)
(let ((cmy1 (colour-as-cmy a))
(cmy2 (colour-as-cmy b)))
(make-colour-cmy
(+ (cyan cmy1) (* frac (- (cyan cmy2) (cyan cmy1))))
(+ (magenta cmy1) (* frac (- (magenta cmy2) (magenta cmy1))))
(+ (yellow cmy1) (* frac (- (yellow cmy2) (yellow cmy1)))))))
(define* (interpolate-colour a b frac #:key (interpolation-type 'linear-cmy))
(case interpolation-type
((linear-cmy)
(interpolate-cmy a b frac))
(else
(raise-exception (make-exception
(make-exception-with-message
"Unrecognised colour interpolation type")
(make-exception-with-irritants interpolation-type))))))
(define-class <colour-component-id> (<object>)
(component
#:init-form (error "Colour component must be specified")
#:init-keyword #:component
#:getter get-colour-component))
(define (colour-component-id? a)
(is-a? a <colour-component-id>))
(define (colour-component-id a)
(make <colour-component-id>
#:component a))
(define (extract-colour-component col component-id)
(cond
((eq? (get-colour-component component-id) 'cyan)
(cyan (colour-as-cmy col)))
((eq? (get-colour-component component-id) 'magenta)
(magenta (colour-as-cmy col)))
((eq? (get-colour-component component-id) 'yellow)
(yellow (colour-as-cmy col)))
((eq? (get-colour-component component-id) 'red)
(red (colour-as-rgb col)))
((eq? (get-colour-component component-id) 'green)
(green (colour-as-rgb col)))
((eq? (get-colour-component component-id) 'blue)
(blue (colour-as-rgb col)))
(else (raise-exception (make-exception
(make-exception-with-message
"Invalid colour component ID")
(make-exception-with-irritants
(get-colour-component component-id)))))))
|
