blob: f1216aea6ecbbed5258aaab34db022c26c69dba3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
|
(define-module (dsil fixture)
#:use-module (oop goops)
#:use-module (ice-9 threads)
#:use-module (ice-9 atomic)
#:use-module (web client)
#:use-module (web http)
#:use-module (web uri)
#:export (<fixture> <fixture-attribute>
start-ola-output patch-fixture
set-attr!
percent->dmxval msb lsb chan))
(use-modules (srfi srfi-1))
(define-class <fixture-attribute> (<object>)
(name
#:init-value 'unnamed-attribute
#:init-keyword #:name
#:getter get-attr-name)
(range
#:init-value '()
#:init-keyword #:range
#:getter get-attr-range)
(translator
#:init-value (lambda (universe start-addr value set-dmx) #f)
#:init-keyword #:translator
#:getter get-attr-translator)
(type
#:init-value 'continuous
#:init-keyword #:type
#:getter get-attr-type)
(home-value
#:init-value 0
#:init-keyword #:home-value
#:getter get-attr-home-value
#:setter set-attr-home-value!)
(value
#:init-value 0
#:getter get-attr-value
#:setter set-attr-value!))
(define-class <fixture> (<object>)
(universe
#:init-value #f
#:init-keyword #:uni
#:getter get-fixture-universe
#:setter set-fixture-universe!)
(start-addr
#:init-value #f
#:init-keyword #:sa
#:getter get-fixture-addr
#:setter set-fixture-addr!)
(friendly-name
#:init-value "Fixture"
#:init-keyword #:friendly-name
#:getter get-fixture-friendly-name
#:setter set-fixture-friendly-name!))
;; List of fixtures
(define patched-fixture-list (make-atomic-box '()))
(define (get-attributes fix)
(slot-ref fix 'attributes))
;; Set a single attribute to home position
(define (home-attr! attr)
(set-attr-value! attr
(get-attr-home-value attr)))
;; Set all attributes of a fixture to home position
(define (home-all! fix)
(for-each home-attr!
(get-attributes fix)))
(define (find-attr fix attr-name)
(find (lambda (a)
(eq? (get-attr-name a)
attr-name))
(get-attributes fix)))
(define (set-attr! fix attr-name value)
(let ((attr (find-attr fix attr-name)))
(when attr (set-attr-value! attr value))))
(define* (patch-fixture class
start-addr
#:key (universe 1) (friendly-name "Fixture"))
(let ((new-fixture (make class
#:sa start-addr
#:uni universe
#:friendly-name friendly-name)))
(home-all! new-fixture)
(atomic-box-set! patched-fixture-list
(cons new-fixture
(atomic-box-ref patched-fixture-list)))
new-fixture))
;; Helper functions for attribute translators
(define (round-dmx a)
(min 255 (max 0 (round a))))
(define (percent->dmxval val)
(round-dmx (/ (* 256 val) 100)))
(define (msb val)
(round-dmx (/ val 256)))
(define (lsb val)
(round-dmx (logand (round val) #b11111111)))
(define (chan channel start-addr)
(- (+ channel start-addr) 1))
;; Scanout
(define (bytevec->string bv)
(string-join
(map
number->string
(u8vector->list bv))
","))
(define (send-to-ola ola-uri ola-socket universe)
(http-post
ola-uri
#:port ola-socket
#:keep-alive? #t
#:headers (acons 'content-type
(parse-header 'content-type
"application/x-www-form-urlencoded")
'())
#:body (string-append "u="
(number->string (car universe))
"&d="
(bytevec->string (cdr universe)))))
(define (start-ola-output)
(letrec* ((ola-uri (build-uri 'http
#:host "127.0.0.1"
#:port 9090
#:path "/set_dmx"))
(ola-socket (open-socket-for-uri ola-uri)))
(begin-thread
(let scanout-loop ()
(let ((universes '()))
;; Helper function called by attribute translators
;; to set individual DMX values
(define (set-dmx universe addr value)
;; Create DMX array for universe if it doesn't exist already
(unless (assq universe universes)
(set! universes (acons universe
(make-u8vector 512 0)
universes)))
;; Set the value in the DMX array
(u8vector-set! (assq-ref universes universe)
(- addr 1) ; u8vector-set indexing starts from zero
(round-dmx value)))
;; Scan out all fixtures
(for-each (lambda (fix)
;; Scan out one fixture
(for-each (lambda (attr)
;; Scan out one attribute
(let ((trans (get-attr-translator attr)))
(trans (get-fixture-universe fix)
(get-fixture-addr fix)
(get-attr-value attr)
set-dmx)))
(get-attributes fix)))
(atomic-box-ref patched-fixture-list))
;; Send everything to OLA
(for-each (lambda (a)
(send-to-ola ola-uri ola-socket a))
universes))
(yield)
(scanout-loop)))))
|
